DI - Method Monitoring 대시보드에는 어떤 규칙이 사용됩니까? - WKB326642

마지막 업데이트
PDF로 저장

Article number: 326642To English version

환경

wcc - Data Intelligence

답변

Data Intelligence에는 Waters 래퍼에 내장된 분석 패키지가 포함되어 있습니다.

Method Monitoring 대시보드에서 고객은 다음 작업을 수행할 수 있습니다.

· 특정 피크 이름이 포함된 모든 수집 지점의 추세를 확인합니다.

· 피크 추세를 사전 정의된 관리도 규칙과 비교하고 규칙 위반을 명확하게 강조 표시합니다.

· 날짜 범위, 프로젝트, 시스템 및 샘플 유형을 기준으로 데이터를 제한합니다.

· 머무름 시간, 피크 면적, 피크 높이 등의 필드별 데이터를 확인합니다.

다음 사항에 유의해야 합니다.

각 대시보드 시트에 적용되고 참조되는 규칙은 Western Electric 및 Nelson 규칙 세트를 따릅니다.
날짜 범위, 프로젝트, 시스템 및 샘플 유형에 필터를 적용하면 평균 및 시그마 기준선 계산에 영향을 미칩니다. 전체 데이터 세트를 기준으로 평균 및 시그마 선을 계산하려면 피크 이름만 설정하고 x축의 파란색 확대/축소 막대를 사용하여 더 작은 데이터 하위 집합을 확인하십시오.
대시보드를 사용자 지정 분석으로 저장하면 모든 규칙 계산을 업데이트할 수 있습니다.

다음 표에서는 대시보드에서 사용할 수 있는 다양한 규칙 유형과 규칙 세트를 비교하여 보여 줍니다.

규칙 범주	관리도 예시	Western Electric 규칙 설명	Nelson 규칙 설명	식별된 문제
3σ를 벗어난 점		한 점이 중심선에서 표준 편차의 3배를 초과하여 벗어나 있습니다. (규칙 1)	한 점이 중심선에서 표준 편차의 3배를 초과하여 벗어나 있습니다. (규칙 1)	샘플이 관리 상태를 크게 벗어났습니다.
2σ를 벗어난 점		연속된 점 3개 중 2개가 중심선의 같은 쪽에서 표준 편차의 2배를 초과하여 벗어나 있습니다. (규칙 2)	연속된 점 3개 중 2개(또는 3개)가 중심선에서 같은 방향으로 표준 편차의 2배를 초과하여 벗어나 있습니다. (규칙 5)	샘플이 관리 상태를 어느 정도 벗어나는 경향이 있습니다.
1σ를 벗어난 점		연속된 점 5개 중 4개가 중심선의 같은 쪽에서 표준 편차의 1배를 초과하여 벗어나 있습니다. (규칙 3)	연속된 점 5개 중 4개(또는 5개)가 중심선에서 같은 방향으로 표준 편차의 1배를 초과하여 벗어나 있습니다. (규칙 6)	샘플이 관리 상태를 약간 벗어나는 강한 경향이 있습니다.
중심선 한쪽에 연속으로 위치한 점		8개 이상의 연속된 점이 중심선의 같은 쪽에 있습니다. (규칙 4)	9개 이상의 연속된 점이 중심선의 같은 쪽에 있습니다. (규칙 2)	장기간 지속되는 편향이 있습니다.
추세		없습니다	6개 이상의 연속된 점이 계속 증가하거나 감소합니다. (규칙 3)	추세가 존재합니다.
진동		없습니다	연속된 14개 이상의 포인트가 증가와 감소를 반복하며 방향이 번갈아 바뀝니다. (규칙 4)	이 정도의 진동은 노이즈 수준을 벗어납니다.
변동 감소		없습니다	연속된 15개의 포인트가 모두 중심선 양쪽에서 중심선으로부터 1 표준 편차 이내에 있습니다. (규칙 7)	표준 편차가 1일 때는 더 큰 변동이 예상됩니다.
변동 증가		없습니다	연속된 8개의 포인트가 있지만 평균으로부터 1 표준 편차 이내에는 하나도 없으며, 포인트는 중심선 양쪽에 있습니다. (규칙 8)	첫 번째 표준 편차 구간에 들어가지 않으면서 중심선 위아래를 오가는 현상은 무작위로 발생하는 경우가 드뭅니다.

임베디드 분석 패키지를 사용하면 데이터 세트 또는 분석 내에서 계산된 필드를 생성할 수 있습니다.

규칙을 구현하기 위해 분석 수준에서 계산된 필드를 생성했습니다.

다음 표들에는 분석에 포함된 모든 계산된 필드가 나와 있습니다.

차트 참조선: 다음 표에는 각 대시보드 시트의 차트 속성에서 참조선에 사용되는 계산된 필드가 나와 있습니다.

계산된 필드 이름	수식
평균	avgOver(AnalysisField, [ ], PRE_AGG)
-1σ	(avgOver(AnalysisField, [ ], PRE_AGG))-(stdevOver(AnalysisField, [ ], PRE_AGG))
-2σ	(avgOver(AnalysisField, [ ], PRE_AGG))-(2*(stdevOver(AnalysisField, [ ], PRE_AGG)))
-3σ	(avgOver(AnalysisField, [ ], PRE_AGG)) - (3*(stdevOver(AnalysisField, [ ], PRE_AGG)))
+1σ	(avgOver(AnalysisField, [ ], PRE_AGG))+(stdevOver(AnalysisField, [ ], PRE_AGG))
+2σ	(avgOver(AnalysisField, [ ], PRE_AGG))+(2*(stdevOver(AnalysisField, [ ], PRE_AGG)))
+3σ	(avgOver(AnalysisField, [ ], PRE_AGG))+(3*(stdevOver(AnalysisField, [ ], PRE_AGG)))

2. 분석 대상 필드를 변경하려면 “AnalysisField” 매개변수를 위한 계산된 필드가 필요합니다. 동일한 형식을 사용하여 새 분석 필드를 추가하면 이 계산된 필드를 확장할 수 있습니다. 또한 이 필드는 Y축의 값 필드로 추가됩니다.

계산된 필드 이름

수식

AnalysisField

ifelse(

${AnalysisField}='Amount',amount,

${AnalysisField}='Area',area,

${AnalysisField}='Height', height,

${AnalysisField}='Retention Time',retentiontime,

${AnalysisField}='USP Resolution',uspresolution,

${AnalysisField}='USP Tailing', usptailing,

${AnalysisField}='Width',width, area)

3. 규칙 1(‘3σ를 벗어난 포인트’ 시트)

규칙을 위반하는 데이터 포인트를 빨간색으로 강조하기 위해 ‘Rule1’ 계산된 필드가 Y축 필드로 추가됩니다.

계산된 필드 이름	수식
Rule1	ifelse(avg(AnalysisField) > avg({ +3σ}) OR avg(AnalysisField) <avg({ -3σ}), avg(AnalysisField), NULL)

4. 규칙 2(2σ를 벗어난 데이터 포인트 시트)

규칙을 위반하는 데이터 포인트를 빨간색으로 강조하기 위해 ‘Rule2’ 계산된 필드가 Y축 필드로 추가됩니다.

+/- 2σ를 벗어난 데이터 포인트를 주황색으로 강조하기 위해 ‘Rule2Flag’ 계산된 필드가 Y축의 필드로 추가됩니다.

계산된 필드 이름	수식
R2tag	ifelse(avg(AnalysisField) > avg({ +2σ}) OR avg(AnalysisField) < avg({ -2σ}), 1, 0)
R2Prev1	lag({ R2tag}, [dateacquired ASC], 1)
R2Prev2	lag({ R2tag}, [dateacquired ASC], 2)
Rule2	ifelse({ R2tag} + { R2Prev1} + { R2Prev2} >= 2, avg(AnalysisField), NULL)
Rule2Flag	ifelse(avg(AnalysisField) > avg({ +2σ}) OR avg(AnalysisField) < avg({ -2σ}), avg(AnalysisField), NULL)

5. 규칙 3(1σ를 벗어난 데이터 포인트 시트)

규칙을 위반하는 데이터 포인트를 빨간색으로 강조하기 위해 ‘Rule3’ 계산된 필드가 Y축 필드로 추가됩니다.

+/- 1σ를 벗어난 데이터 포인트를 주황색으로 강조하기 위해 ‘Rule3Flag’ 계산된 필드가 Y축의 필드로 추가됩니다.

계산된 필드 이름	수식
R3tag	ifelse(avg(AnalysisField) > avg({ +1σ}) OR avg(AnalysisField) < avg(-{ -1σ}), 1, 0)
R3Prev1	lag({ R3tag}, [dateacquired ASC], 1)
R3Prev2	lag({ R3tag}, [dateacquired ASC], 2)
R3Prev3	lag({ R3tag}, [dateacquired ASC], 3)
R3Prev4	lag({ R3tag}, [dateacquired ASC], 4)
Rule3	ifelse({ R3tag} + { R3Prev1} + { R3Prev2} + { R3Prev3} +{ R3Prev4} >= 4,avg(AnalysisField), NULL)
Rule 3Flag	ifelse(avg(AnalysisField) > avg({ +1σ}) OR avg(AnalysisField) < avg(-{ -1σ}), avg(AnalysisField), NULL)

6. 규칙 4(평균의 동일한 쪽에 있는 연속 데이터 포인트 시트)

규칙을 위반하는 데이터 포인트를 빨간색으로 강조하기 위해 ‘Rule4’ 계산된 필드가 Y축의 필드로 추가됩니다.

현재 데이터 포인트와 이전 데이터 포인트가 평균의 동일한 쪽에 있는 경우 해당 데이터 포인트를 주황색으로 강조하기 위해 ‘Rule4Flag’ 계산된 필드가 Y축의 필드로 추가됩니다.

계산된 필드 이름	수식
R4tag	ifelse(AnalysisField > avgOver(AnalysisField, [], PRE_AGG), 1, -1)
Rule4	ifelse(avg({ R4tag}) <> 0 AND lag(avg({ R4tag}), [dateacquired ASC], 1) = avg({ R4tag}) AND lag(avg({ R4tag}), [dateacquired ASC], 2) = avg({ R4tag}) AND lag(avg({ R4tag}), [dateacquired ASC], 3) = avg({ R4tag}) AND lag(avg({ R4tag}), [dateacquired ASC], 4) = avg({ R4tag}) AND lag(avg({ R4tag}), [dateacquired ASC], 5) = avg({ R4tag}) AND lag(avg({ R4tag}), [dateacquired ASC], 6) = avg({ R4tag}) AND lag(avg({ R4tag}), [dateacquired ASC], 7) = avg({ R4tag}) , avg(AnalysisField), NULL)
Rule4Flag	ifelse((AnalysisField > avgOver(AnalysisField, [], PRE_AGG) OR AnalysisField < avgOver(AnalysisField, [], PRE_AGG)), AnalysisField, NULL)

7. 규칙 5(추세 시트)

규칙을 위반하는 데이터 포인트를 빨간색으로 강조하기 위해 ‘Rule5’ 계산된 필드가 Y축 필드로 추가됩니다.

이전 데이터 포인트보다 상승하거나 하락한 데이터 포인트를 황색으로 강조하기 위해 ‘Rule5Flag’ 계산된 필드를 Y축에 필드로 추가합니다.

계산된 필드 이름

수식

Direction

ifelse(avg(AnalysisField) > lag(avg(AnalysisField), [dateacquired ASC], 1), 1,

ifelse(avg(AnalysisField) < lag(avg(AnalysisField), [dateacquired ASC], 1), -1, 0))

Rule5

ifelse({ Direction} <> 0

AND { Direction} = lag({ Direction}, [dateacquired ASC], 1)

AND { Direction} = lag({ Direction}, [dateacquired ASC], 2)

AND { Direction} = lag({ Direction}, [dateacquired ASC], 3)

AND { Direction} = lag({ Direction}, [dateacquired ASC], 4)

AND { Direction} = lag({ Direction}, [dateacquired ASC], 5),

avg(AnalysisField), NULL)

Rule5Flag

ifelse((avg(AnalysisField) > lag(avg(AnalysisField), [dateacquired ASC], 1)

OR avg(AnalysisField) < lag(avg(AnalysisField), [dateacquired ASC], 1)),

avg(AnalysisField), NULL)

8. 규칙 6(교대 변동 시트)

규칙을 위반하는 데이터 포인트를 빨간색으로 강조하기 위해 ‘Rule6’ 계산된 필드를 Y축에 필드로 추가합니다.

이전 데이터 포인트와 비교해 방향이 바뀐 데이터 포인트를 황색으로 강조하기 위해 ‘Rule6Flag’ 계산된 필드를 Y축에 필드로 추가합니다.

계산된 필드 이름	수식
Alternating	ifelse({ Direction} * lag({ Direction},[dateacquired ASC], 1) = -1, 1, 0)
Rule6	ifelse({ Alternating} =1 AND lag({ Alternating}, [dateacquired ASC], 1) =1 AND lag({ Alternating}, [dateacquired ASC], 2) =1 AND lag({ Alternating}, [dateacquired ASC], 3) =1 AND lag({ Alternating}, [dateacquired ASC], 4) =1 AND lag({ Alternating}, [dateacquired ASC], 5) =1 AND lag({ Alternating}, [dateacquired ASC], 6) =1 AND lag({ Alternating}, [dateacquired ASC], 7) =1 AND lag({ Alternating}, [dateacquired ASC], 8) =1 AND lag({ Alternating}, [dateacquired ASC], 9) =1 AND lag({ Alternating}, [dateacquired ASC], 10) =1 AND lag({ Alternating}, [dateacquired ASC], 11) =1 AND lag({ Alternating}, [dateacquired ASC], 12) =1 AND lag({ Alternating}, [dateacquired ASC], 13) =1 AND lag({ Alternating}, [dateacquired ASC], 14) =1, avg(AnalysisField), NULL)
Rule6Flag	ifelse({ Direction} * lag({ Direction},[dateacquired ASC], 1) = -1, avg(AnalysisField), NULL)

9. 규칙 7(변동 축소 시트)

규칙을 위반하는 데이터 포인트를 빨간색으로 강조하기 위해 ‘Rule7’ 계산된 필드를 Y축에 필드로 추가합니다.

±1σ 범위 내의 데이터 포인트를 황색으로 강조하기 위해 ‘Rule7Flag’ 계산된 필드를 Y축에 필드로 추가합니다.

계산된 필드 이름	수식
R7Prev1	lag({ Rule7Flag}, [dateacquired ASC], 1)
R7Prev2	lag({ Rule7Flag}, [dateacquired ASC], 2)
R7Prev3	lag({ Rule7Flag}, [dateacquired ASC], 3)
R7Prev4	lag({ Rule7Flag}, [dateacquired ASC], 4)
R7Prev5	lag({ Rule7Flag}, [dateacquired ASC], 5)
R7Prev6	lag({ Rule7Flag}, [dateacquired ASC], 6)
R7Prev7	lag({ Rule7Flag}, [dateacquired ASC], 7)
R7Prev8	lag({ Rule7Flag}, [dateacquired ASC], 8)
R7Prev9	lag({ Rule7Flag}, [dateacquired ASC], 9)
R7Prev10	lag({ Rule7Flag}, [dateacquired ASC], 10)
R7Prev11	lag({ Rule7Flag}, [dateacquired ASC], 11)
R7Prev12	lag({ Rule7Flag}, [dateacquired ASC], 12)
R7Prev13	lag({ Rule7Flag}, [dateacquired ASC], 13)
R7Prev14	lag({ Rule7Flag}, [dateacquired ASC], 14)
Rule7	ifelse({ Rule7Flag} + { R7Prev1} + { R7Prev2} + { R7Prev3} + { R7Prev4} + { R7Prev5} + { R7Prev6} + { R7Prev7} + { R7Prev8} + { R7Prev9} + { R7Prev10} + { R7Prev11} + { R7Prev12} + { R7Prev13} + { R7Prev14} >= 14, avg(AnalysisField), NULL)
Rule7Flag	ifelse(avg(AnalysisField) < avg({ +1σ}) AND avg(AnalysisField) > avg({ -1σ}), avg(AnalysisField), NULL)

10. 규칙 8(변동 증가 시트)

규칙을 위반하는 데이터 포인트를 빨간색으로 강조하기 위해 ‘Rule8’ 계산된 필드가 Y축의 필드로 추가됩니다.

+/- 1σ 범위를 벗어난 데이터 포인트를 황색으로 강조하기 위해 ‘Rule8Flag’ 계산된 필드를 Y축 필드로 추가합니다.

계산된 필드 이름	수식
R8Prev1	lag({ Rule8Flag}, [dateacquired ASC], 1)
R8Prev2	lag({ Rule8Flag}, [dateacquired ASC], 2)
R8Prev3	lag({ Rule8Flag}, [dateacquired ASC], 3)
R8Prev4	lag({ Rule8Flag}, [dateacquired ASC], 4)
R8Prev5	lag({ Rule8Flag}, [dateacquired ASC], 5)
R8Prev6	lag({ Rule8Flag}, [dateacquired ASC], 6)
R8Prev7	lag({ Rule8Flag}, [dateacquired ASC], 7)
Rule8	ifelse({ Rule8Flag} + { R8Prev1} + { R8Prev2} + { R8Prev3} + { R8Prev4} +{ R8Prev5} + { R8Prev6} + { R8Prev7} >= 7, avg(AnalysisField), NULL)
Rule8Flag	ifelse(avg(AnalysisField) > avg({ +1σ}) OR avg(AnalysisField) < avg({ -1σ}), avg(AnalysisField), NULL)

추가 정보

id326642, consecutive, noise, X-Axis, Y-Axis